Excelfunktionen PRODUKTSUMMA multiplicerar cellområden eller matriser tillsammans och returnerar summan av produkten. PRODUKTSUMMA är en otroligt varierande funktion som kan användas för att räkna och summera på samma sätt som ANTAL.OMF eller SUMMA.OMF, men med mer anpassbarhet. Andra funktioner kan väldigt enkelt användas inuti PRODUKTSUMMA för att ytterligare utöka funktionaliteten.
Ändamål
Multiplicera och sedan summera matriser
Returvärde
Resultatet av multiplicerade och summerade matriser
Syntax
=PRODUKTSUMMA (matris1, [matris2], …)
Argument
matris1 – Den första matrisen eller cellområdet som ska multipliceras och sedan summera
matris2 – [valfritt] Den andra matrisen eller cellområdet som ska multipliceras och sedan summera
Användningsanteckningar
PRODUKTSUMMA-funktionen multiplicerar matriser med varandra och returnerar summan av produkterna. Om endast en matris levereras summerar PRODUKTSUMMA-funktionen helt enkelt alla matrisens objekt. Upp till 255 enskilda cellområden eller matriser kan läggas in.
PRODUKTSUMMA är en otroligt mångsidig funktion med många användningsområden. Eftersom den hanterar matriser på ett elegant sätt kan man använda den för att behandla och beräkna cellområden på smarta och smidiga sätt.
Matriser och Excel 365
PRODUKTSUMMA kan användas för att skapa matrisformler som inte kräver kortkommandot Ctrl + Skift + Retur. Detta är en nödvändig orsak till att PRODUKTSUMMA har så ofta använts för att skapa mer avancerade formler. Ett vanligt problem med matrisformler är att de kan returnera felaktiga resultat om de inte anges med kortkommandot Ctrl + Skift + Retur. Detta innebär att om man glömmer att använda kortkommandot när man justerar en formel kan hela resultatet plötsligt ändras, även om själva formeln alls har inte ändrats. Att använda PRODUKTSUMMA innebär att formlerna fungerar i alla versioner av Excel utan särskild behandling.
I Excel 365 hanterar formelmotorn matriser internt, vilket innebär att du ofta kan använda funktionen SUMMA i stället för PRODUKTSUMMA i en matrisformel och få fram samma resultat. Det finns alltså inget behov av att mata in formeln på ett speciellt sätt. Å andra hand, om samma formel öppnas i en tidigare version av Excel krävs åter igen kortkommandot Ctrl + Skift + Retur.
Slutsatsen är att PRODUKTSUMMA är ett tryggare alternativ om ett kalkylblad kommer eventuellt att användas av någon som har en version av Excel före Excel 365.
Exempel på PRODUKTSUMMA
Det klassiska PRODUKTSUMMA-exemplet illustrerar hur man kan beräkna en summa direkt utan en så kallad hjälpkolumn. I kalkylbladet nedan skulle man till exempel kunna använda PRODUKTSUMMA för att få fram summan av alla tal i kolumn G utan att använda sig av kolumn G alls:
För att utföra den här beräkningen använder PRODUKTSUMMA alla värden i kolumnerna E och F direkt:
=PRODUKTSUMMA(E5:E14;F5:F14)
Resultatet blir detsamma som om att man summera alla värden i kolumn G. Formeln utvärderas så här:
= PRODUKTSUMMA(E5:E14;F5:F14)
= PRODUKTSUMMA({10;6;14;9;11;10;8;9;11;10};{150;180;150;160;180;180;150;160;180;160})
= PRODUKTSUMMA({1500;1080;2100;1440;1980;1800;1200;1440;1980;1600})
= 16120
Denna metod av att använda PRODUKTSUMMA kan vara praktisk, särskilt när det inte finns något utrymme (eller behov) för en hjälparkolumn med en intermediär beräkning. Den vanligaste användningen av PRODUKTSUMMA i verkligheten är dock att tillämpa villkorlig logik i situationer som kräver mer flexibilitet än kan erbjudas av funktioner som SUMMA.OMF och ANTAL.OMF.
PRODUKTSUMMA för villkorade belopp och räkningar
Anta att du har vissa orderdata i A2:B6, med städer i kolumn A och försäljning i kolumn B:
| Stad | Försäljning (milj.) |
|---|---|
| Malmö | 75 |
| Göteborg | 100 |
| Stockholm | 125 |
| Göteborg | 125 |
| Stockholm | 150 |
Med hjälp av PRODUKTSUMMA kan man räkna den totala försäljningen för Stockholm med denna formel:
=PRODUKTSUMMA(–(A2:A6=”Stockholm”))
Och man kan summera den totala försäljningen för Stockholm med denna formel:
=PRODUKTSUMMA(–(A2:A6=”Stockholm”),B2:B6)
Tips: Dubble minustecken är ett vanligt knep som används i mer avancerade Excelformler för att tvinga SANT- och FALSKT-satser till att bli 1:or och 0:or.
För exemplet ovan har vi en bildlig representation av de två matriserna som först bearbetas av PRODUKTSUMMA:
matris1 matris2
FALSKT 75
FALSKT 100
SANT 125
FALSKT 125
SANT 150
Varje matris har 5 objekt. Matris1 innehåller SANT/FALSKT-värdena som är resultatet av uttrycket A2:A6=”Stockholm” och matris2 innehåller alla värdena i B2:B6. Varje artikel i matris1 multipliceras med motsvarande objekt i matris2. Dock blir resultatet i det aktuella läget noll eftersom SANT- och FALSKT-värdena i matris1 utvärderas som noll. Vi vill så att objekten i matris1 ska vara numeriska, och det är här dubbla minustecknen blir användbart.
Dubbla minustecken(–)
Dubbla minustecken (–) är ett av flera sätt att tvinga SANT och FALSKT till att bli deras numeriska motsvarigheter, alltså 1 och 0. Så fort de har blivit 1:or och 0:or, vi kan utföra olika operationer på matriserna med boolesk logik. Tabellen nedan visar resultatet i matris1, baserat på formeln ovan, efter att de dubbla minustecknen (–) har ändrat SANT- och FALSKT-värdena till 1:or och 0:or.
array1 array2 Produkt
0 * 75 = 0
0 * 100 = 0
1 * 125 = 125
0 * 125 = 0
1 * 150 = 150
Summa 275
Översätter man tabellen ovan till matriser utvärderas formeln så här:
=PRODUKTSUMMA({0;0;1;0;1};{75;100;125;125;150})
PRODUKTSUMMA multiplicerar sedan matris1 med matris2, vilket resulterar i en enda matris:
=PRODUKTSUMMA ({0;0;125;0;150})
Slutligen returnerar PRODUKTSUMMA summan av alla värden i matrisen, alltså 275.
Förkortad syntax
Du kommer ofta att se formeln som beskrivs ovan skriven på ett annat sätt:
=PRODUKTSUMMA ((A2:A6=”Stockholm”)*B2:B6)
Denna formel returnerar det korrekta svaret – 275
Här finns bara en matris som matas in i PRODUKTSUMMA-funktionen. Resultatet är detsamma, men syntaxen är mer kompakt eftersom det inte finns något behov av att använda dubbla minustecken (–). Detta beror på att den matematiska åtgärden för multiplikation (*) tvingar automatiskt SANT- och FALSKT-värdena från (A2:A6=”Stockholm”) till 1:or och 0:or. Den här syntaxen visas ofta i PRODUKTSUMMA-formler, eftersom den visar ett sätt att använda boolesk algebra för att skapa den logik som behövs i mer komplicerade scenarier.
Ignorera tomma celler
Vill du ignorera tomma celler med PRODUKTSUMMA kan du använda sådant uttryck:
cellområde<>””
I exemplet nedan ignorerar formlerna i G5 och G6 de två celler i kolumn D som inte innehåller ett värde:
=PRODUKTSUMMA(–(C5:C15<>””))
=PRODUKTSUMMA(–(C5:C15<>”)*D5:D15)
PRODUKTSUMMA med andra funktioner
PRODUKTSUMMA kan använda andra funktioner som argument. Man ser ofta PRODUKTSUMMA-funktioner som använder med funktionen LÄNGD för att räkna totalt antal tecken inom ett område, eller med funktioner som ÄRTOM, ÄRTAL, osv. Normalt sätt är dessa inte matrisfunktioner, men när de får ett cellområde skapar de en “resultatmatris”. Eftersom PRODUKTSUMMA är byggd för att fungera med matriser kan den genomföra beräkningar direkt på matriserna. Detta kan vara ett bra sätt att spara utrymme i ett kalkylblad eftersom det tar bort behovet av en hjälparkolumn.
Låt oss säga till exempel att du har 10 olika textvärden i B1:B10 och att du vill räkna ihop det totala antalet tecken för alla 10 värden. Du kan lägga till en hjälpkolumn i kolumn C som använder den här formeln: LÄNGD(B1) för att räkna antalet tecken i varje cell. Då kan du använda SUMMA för att summera alla de 10 resulterande numren. Med PRODUKTSUMMA kan du dock skriva en formel som gör allting samtidigt:
=PRODUKTSUMMA(LÄNGD(A1:A10))
När LÄNGD används med ett område som B1:B10 kommer den att returnera en matris med 10 värden. PRODUKTSUMMA summerar sedan helt enkelt alla dessa värden och returnerar resultatet, utan att någon hjälpkolumn behövs.
Anteckningar
- PRODUKTSUMMA behandlar icke-numeriska objekt i matriser som nollor.
- Alla matrisargument som anges måste ha samma storlek, annars kommer PRODUKTSUMMA att generera ett fel.
- Logiska tester i matriser skapar SANT- och FALSKT-värden. I de flesta fall kommer man vilja tvinga dessa till att bli till 1:or och 0:or.
- PRODUKTSUMMA kan ofta använda resultatet av andra funktioner direkt.
